Graphics

We often use the XPression Video Coder to transcode custom graphics made in the newsroom to the XPression video codec for use in templates.

Right now all of those graphics have to go through production before they can be used. Once they get to us they each follow the exact same process, sharing the same import and export locations, so we're just kind of a speed bump in the whole operation.

Are there any command line options for the XPression video coder? Or any other way anyone has come up with to automate this process?

Ross sells a system that has the ability to do this, Ross XPression Incoder. You basically set up watchfolders that you drop content to to be transcoded to the XPression codec and it'll output it directly to your XPression clip store. I do believe there is also a setup you can do in After Effects and Adobe Media Encoder to encode in the XPression codec natively from your projects so that you don't have to worry about using Video Coder. There used to be a tutorial video on how to do this, but I'm not sure if it's still out there.

Video coder does accept some command line parameters:

/listcodecs  - which will show a dialog box listing all available codec names
/writecodecs - will write a list with available codec names to codecs.txt located in the current folder
source=[filename]
target=[filename]
codec=[codecname]

targetframerate=[framerate]

e.g. videocoder.exe source=test.mov target=test.avi targetframerate=29.97

Wow, thanks Brian! That's exactly what I needed. It's odd that they never bothered to write a /help command.

For anyone else who's looking to do this, below is the script I'm using. I just leave it running on the computer with Video Coder installed. Set [WATCH FOLDER DIRECTORY], [FRAME RATE], and [POLLING DELAY] to suit.

@echo off

SET dirWatchFolder=[WATCH FOLDER DIRECTORY]

if not exist "%dirWatchFolder%" md "%dirWatchFolder%"
cd /D %dirWatchFolder%
echo XPression Video Coder Utility
echo Monitoring %CD%...
:loop
for %%a in (*.mp4 *.mpg *.mpeg *.avi *.mov *.mxf) do (
	for %%b in (.\Completed .\Processing .\Failed .\Old) do (
		if not exist %%b md %%b
	)
	move /Y ".\%%a" ".\Old\%%~nxa" >nul
	echo Encoding %%~nxa...
	pushd "%ProgramFiles(x86)%\XPressionStudio"
	VideoCoder.exe source="%dirWatchFolder%\Old\%%~nxa" target="%dirWatchFolder%\Processing\%%~na.avi" codec="XPression Video Codec 5.7" targetframerate=[FRAME RATE]
	popd
	if  exist ".\Processing\%%~na.avi" (
		move /Y ".\Processing\%%~na.avi" ".\Completed\%%~na.avi" >nul
		echo Completed.
	) else (
		move /Y ".\Old\%%~nxa" ".\Failed\%%~nxa" >nul
		echo Failed.
	)
	echo Monitoring...
)
ping -n [POLLING DELAY (IN SECONDS)] localhost >nul
goto :loop